Enhance an ABAP Core Data Services (CDS) View in SAP Business Technology Platform (BTP) ABAP Environment

Next, you will make the Agency field more readable by adding the agency name to the ID, using a text association. CDS associations are simply specifications of joins, always in the same place in the syntax. The main advantage of an association is reuse: Once you have specified an association once, you can conveniently string several associations together in a path. In this case, however, you will use a simple association.

For more information, see:

• ABAP Keyword Documentation: CDS - Associations

1. Add the following statement to your CDS entity, Z_I_TRAVEL_R_000, just before the list of fields. The first statement creates an association from the source CDS entity Z_I_TRAVEL_R_000 to the target CDS entity /DMO/I_Agency, joined on the field AgencyID. The source entity is represented by the alias $projection, because you cannot use the original name in a path statement. The target entity is represented by its alias name _Agency.

   CDS Copy

     association [1..1] to /DMO/I_Agency as _Agency on $projection.AgencyID = _Agency.AgencyID

ABAP has many built-in SQL functions for both numeric and string fields.

For more information on these functions, see : ABAP Keyword Documentation: SQL Functions.

You will use a simple one to easily merge two fields. The two fields are provided by the association _Customer.

1. Add an association.

   CDS Copy

       association [1..1] to /DMO/I_Customer as _Customer on $projection.CustomerID = _Customer.CustomerID

It would be nice to find out how much money each Agency has received in total. To do this, you first need to convert all the sums paid to one currency. To do this, you will again use a built-in function. For more information, see the ABAP Keyword Documentation: ABAP CDS - Conversion Functions for Units and Currencies

1. Convert the price (TotalPrice) of each line item to US Dollars. Again, you do this using a built-in conversion function. You simply have to define the variables you are using for amount, source currency, etc, and the built-in function does the rest.

   You need to cast the character value 'USD' to the correct type and length, abap.cuky( 5 ).

   You may get a warning: “Reference information missing…”. Ignore this for now.

   CDS Copy

   @Semantics.amount.currencyCode: 'CurrencyCode'
   currency_conversion(
   amount => TotalPrice,
   source_currency => CurrencyCode,
   round => 'X',
   target_currency => cast('USD' as abap.cuky( 5 )),
   exchange_rate_date => cast('20200429' as abap.dats),
   error_handling => 'SET_TO_NULL' )
   as PriceInUSD,  

The code for your CDS entity should look like this:

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Travel Model View Entity - Read Only'
@Metadata.ignorePropagatedAnnotations: true
@Metadata.allowExtensions: true
@Search.searchable: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity Z_I_TRAVEL_R_ENHANCED as select from /DMO/I_Travel_U

 association [1..1] to /DMO/I_Agency   as _Agency       on $projection.AgencyID = _Agency.AgencyID
  association [1..1] to /DMO/I_Customer as _Customer     on $projection.CustomerID = _Customer.CustomerID

{

      ///DMO/I_Travel_U

  key TravelID,
      @Consumption.valueHelpDefinition: [{entity: {name: '/DMO/I_Agency', element: 'AgencyID'}}]
      @ObjectModel.text.association: '_Agency'
      AgencyID,

      @Consumption.valueHelpDefinition: [{entity: {name: '/DMO/I_Customer', element: 'CustomerID' }}]
      @ObjectModel.text.association: '_Customer'
      CustomerID,

      concat_with_space(_Customer.Title, _Customer.LastName, 1) as Addressee,
      BeginDate,
      EndDate,
      
      @Semantics.amount.currencyCode: 'CurrencyCode'      
      BookingFee,

      @Semantics.amount.currencyCode: 'CurrencyCode'
      TotalPrice,

      //Currency Conversion
      @Semantics.amount.currencyCode: 'CurrencyCode'
      currency_conversion(
      amount => TotalPrice,
      source_currency => CurrencyCode,
      round => 'X',
      target_currency => cast('USD' as abap.cuky( 5 )),
      exchange_rate_date => cast('20200429' as abap.dats),
      error_handling => 'SET_TO_NULL' )                         as PriceInUSD,

      CurrencyCode,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.90
      Memo,
      Status,
      LastChangedAt,

      /* Associations */
      //DMO/I_Travel_U
      _Agency,
      _Booking,
      _Currency,
      _Customer,
      _TravelStatus

}

At the moment, your application is a simple list. It would be nice to click on a row, i.e. a travel, and get more details in a separate page, known as an object page. Later you can add details from other CDS entities using associations. For more information on object pages, see SAP Help Portal: Defining UI Annotations

1. First add the page itself. Add the following annotation to your metadata extension, just after the opening curly bracket:

   CDS Copy

   @UI.facet: [ { id:              'Travel',
                   purpose:         #STANDARD,
                   type:            #IDENTIFICATION_REFERENCE,
                   label:           'Travel',
                   position:        10 } ]

You will now add more information to the object page by creating:

• A CDS entity for bookings
• Adding a second UI facet to the travel metadata extension

You will also create a parent-child hierarchy for these two entities. Your business object will then consist of a tree of nodes linked by a special associations known as a composition. For more information on this relationship, see Defining the Data Model in CDS Views, particularly the first two sections, Travel Root View /DMO/I_Travel_U and Booking View /DMO/I_Booking_U.

1. In the Package Explorer, select Data Definition, then choose New Data Definition from the context menu.

   

2. Enter the following:

   • Name = Z_I_BOOKING_R_000
   • Description = Consumption view from /DMO/I_BOOKING_U
   • Referenced Object = /DMO/I_BOOKING_U

3. Choose the same transport request, then choose Next. Do not choose Finish.

4. Finally, choose Use template then choose Define view. Then choose Finish.

Your CDS entity appears in a new editor. We will fix the errors now.

6. Change the @AccessControl.authorizationCheck: to #NOT_REQUIRED.

1. Add the following to Z_I_BOOKING_000, using Auto-complete (Ctrl+Space). Then Save, but DO NOT yet activate your entity.

   CDS Copy

   association to parent Z_I_TRAVEL_R_000 as _Travel
     on $projection.TravelID = _Travel.TravelID

1. Add semantic annotations as follows:

   CDS Copy

   @Semantics.amount.currencyCode: 'Currency_Code'
   FlightPrice          as Flight_Price,
   
   @Semantics.currencyCode: true
   CurrencyCode         as Currency_Code,

1. First, allow metadata extensions to your CDS entity by adding the following annotation just after the @EndUserText.label: 'Consumption view from /DMO/I_BOOKING_U' annotation:

   CDS Copy

   @Metadata.allowExtensions: true

1. Also, add the entity Z_I_BOOKING_R_000 to the service definition Z_EXPOSE_TRAVEL_R_000:

   CDS Copy

   @EndUserText.label: 'Expose travel Service 000'
   define service Z_EXPOSE_TRAVEL_R_000 {
   expose Z_I_TRAVEL_R_000 as Travel;
   expose Z_I_BOOKING_R_000 as Booking;
   }

1. In metadata extension Z_MDE_TRAVEL_000, before the square bracket, insert a comma after the Travel facet, then insert the Booking facet to the Travel metadata extension, so that your code looks like this:

   CDS Copy

   @UI.facet: [ { id:              'Travel',
                   purpose:         #STANDARD,
                   type:            #IDENTIFICATION_REFERENCE,
                   label:           'Travel',
                   position:        10 } ,
                   { id:              'Booking',
                   purpose:         #STANDARD,
                   type:            #LINEITEM_REFERENCE,
                   label:           'Booking',
                   position:        20,
                   targetElement:   '_Booking'} ]

You can also display information from another entity using an association.

1. In the CDS entity Z_I_BOOKING_R_000, add an association from Booking to Connection.

   CDS Copy

       association [1..1] to /DMO/I_Connection as _Connection on $projection.ConnectionId = _Connection.ConnectionID

1. Add the following code, immediately after the element DistanceUnit:

   CDS Copy

   case
       when _Connection.Distance >= 2000 then 'long-haul flight'
       when _Connection.Distance >= 1000 and
        _Connection.Distance <  2000 then 'medium-haul flight'
       when _Connection.Distance <  1000 then 'short-haul flight'
                         else 'error'
   end                      as Flight_type,

• Blog post: From Open SQL Joins to CDS Associations

• SAP Help Portal: Defining UI Annotations

• SAP Help Portal: Defining CDS Annotations for Metadata-Driven UIs

• Troubleshooting: Blog post: Find Errors in Metadata Extensions, by Andre Fischer

• Troubleshooting: Blog post: Use the SAP Gateway Error Log in ADT, by Andre Fischer